#!perl -T
# $RedRiver: 50-network.t,v 1.4 2007/02/05 23:11:21 andrew Exp $

use Test::More tests => 7;
use File::Spec;

BEGIN {
	use_ok( 'Net::Telnet::Trango' );
}

diag("Testing Net::Telnet::Trango $Net::Telnet::Trango::VERSION, Perl $], $^X");
diag("  Generic tests");

my $cfg_file = File::Spec->catfile('t', 'tests.cfg');
my ($cir, $mir) = (128, 256);

SKIP: {
    my $skipped = 6;
    my %cfg;
    if (-e $cfg_file) {
        if (open my $fh, $cfg_file) {
            while (<$fh>) {
                chomp;
                my ($key, $value) = split /\t/, $_, 2;
                $cfg{$key} = $value;
            }
            close $fh;
        }
    }

    my $type = 'AP';
    my ($host, $pass, $su_id, $su_mac);

    if ($cfg{$type} && $cfg{$type} =~ /^(\d+\.\d+\.\d+.\d+)$/) {
        $host = $1;
    }

    skip 'No valid ' . $type . ' in config file',        $skipped unless $host; 

    if ($cfg{$type . '_PASSWD'} && $cfg{$type . '_PASSWD'} =~ /^(.*)$/) {
        $pass = $1;
    }

    skip 'No valid ' . $type . '_PASSWD in config file', $skipped unless $pass;

    if ($cfg{SU_ID} && $cfg{SU_ID} =~ /^(\d+)$/) {
        $su_id= $1;
    }

    skip 'No valid SU_ID in config file', $skipped unless $su_id;

    if ($cfg{SU_MAC} && length $cfg{SU_MAC} >= 12 && $cfg{SU_MAC} =~ /^(.*)$/) {
        $su_mac = $1;
    }

    skip 'No valid SU_MAC in config file', $skipped unless $su_mac;

    my $t;
    ok($t = Net::Telnet::Trango->new(), "Instantiating object");

    $t->input_log('input.log'); # XXX Debugging

    ok($t->open($host), "Opening connection to $host");

    ok($t->is_connected, "connected");

    ok($t->login($pass), "Logging in");

    ok($t->logged_in, "logged in");


    my $sudb;
    ok($sudb = $t->sudb_view, "Getting sudb");

    use YAML;
    print Dump $sudb;

    my $result;
    ok($result = $t->sudb_add($su_id, 'reg', $cir, $mir, $su_mac), "Adding su");

    if ( (! $result ) && $t->last_error ) {
        diag('ERR: ' . $t->last_error);
    }

    ok($result = $t->save_sudb, "Saving sudb");

    if ( (! $result ) && $t->last_error ) {
        diag('ERR: ' . $t->last_error);
    }

    $result = $t->opmode('ap y');
    if ( (! $result ) && $t->last_error ) {
        diag('ERR: ' . $t->last_error);
    }

    my $opmode;
    ok($opmode = $t->opmode, "getting current opmode");

    if (ref $opmode eq 'HASH' && $opmode->{ERR}) {
        diag("Error: $opmode->{ERR}");
    }

    is($opmode->{Opmode}, 'ap', "Checking opmode is ap");

    ok($t->bye, "Goodbye");
}