#!/usr/bin/perl -T

# $AFresh1: perl_strmode.pl,v 1.1.1.1 2011/03/27 20:54:35 andrew Exp $
#
# Copyright (c) 2011 Andrew Fresh <andrew@afresh1.com>
#
# Permission to use, copy, modify, and distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.

use warnings;
use strict;
use 5.010;

use Fcntl ':mode';

sub strmode {

    # Perl port of OpenBSD: lib/libc/string/strmode.c,v 1.7
    # by Andrew Fresh <andrew@afresh1.com>

    my ($mode) = @_;
    my $p = '';

    # print type
    given ( $mode & S_IFMT ) {
        when (S_IFDIR)  { $p .= 'd' }    # directory
        when (S_IFCHR)  { $p .= 'c' }    # character special
        when (S_IFBLK)  { $p .= 'b' }    # block special
        when (S_IFREG)  { $p .= '-' }    # regular
        when (S_IFLNK)  { $p .= 'l' }    # symbolic link
        when (S_IFSOCK) { $p .= 's' }    # socket

        #ifdef S_IFIFO XXX How important is this ifdef?
        when (S_IFIFO) { $p .= 'p' }     # fifo

        #endif
        default { $p .= '?' }            # unknown
    }

    # usr
    $p .= ( $mode & S_IRUSR ) ? 'r' : '-';
    $p .= ( $mode & S_IWUSR ) ? 'w' : '-';
    given ( $mode & ( S_IXUSR | S_ISUID ) ) {
        when (0)                   { $p .= '-' }
        when (S_IXUSR)             { $p .= 'x' }
        when (S_ISUID)             { $p .= 'S' }
        when ( S_IXUSR | S_ISUID ) { $p .= 's' }
    }

    # group
    $p .= ( $mode & S_IRGRP ) ? 'r' : '-';
    $p .= ( $mode & S_IWGRP ) ? 'w' : '-';
    given ( $mode & ( S_IXGRP | S_ISGID ) ) {
        when (0)                   { $p .= '-' }
        when (S_IXGRP)             { $p .= 'x' }
        when (S_ISGID)             { $p .= 'S' }
        when ( S_IXGRP | S_ISGID ) { $p .= 's' }
    }

    # other
    $p .= ( $mode & S_IROTH ) ? 'r' : '-';
    $p .= ( $mode & S_IWOTH ) ? 'w' : '-';
    given ( $mode & ( S_IXOTH | S_ISVTX ) ) {
        when (0)                   { $p .= '-' }
        when (S_IXOTH)             { $p .= 'x' }
        when (S_ISVTX)             { $p .= 'T' }
        when ( S_IXOTH | S_ISVTX ) { $p .= 't' }
    }
    $p .= ' ';    # will be a '+' if ACL's implemented

    return $p;
}

my @files = @ARGV;
@files = '.' unless @files;

foreach my $file (@files) {
    next unless -e $file;
    my ( $mode, $nlink, $uid, $gid, $size, $mtime )
        = ( stat(_) )[ 2 .. 5, 7, 9 ];

    my $time = localtime($mtime);
    $time =~ s/^\w+\s+//;

    printf "%s %2s %-7s %-7s %8d %s %s\n",
        strmode($mode),
        $nlink,
        ( getpwuid($uid) )[0],
        ( getgrgid($gid) )[0],
        $size, $time, $file;
}