#!/usr/bin/perl
# $AFresh1: rt_invoices.pl,v 1.43 2011/12/30 03:30:51 andrew Exp $
########################################################################
# Copyright (c) 2011 Andrew Fresh <andrew@afresh1.com>
#
# Permission to use, copy, modify, and distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
########################################################################
use strict;
use warnings;

use 5.010;

use Template;
use RT::Client::REST;
use RT::Client::REST::Ticket;
use RT::Client::REST::User;

use File::Path;
use DateTime;

use lib './lib';    # XXX This is fragile, there are better ways
use RTI::Config;
use RTI::State;

my $config = RTI::Config->new();
my $state  = RTI::State->new( $config->get('state') );

my $rt_conf = $config->get('rt');
my $rt      = RT::Client::REST->new(
    server  => $rt_conf->{server},
    timeout => $rt_conf->{timeout},
);
my $tickets = RT::Client::REST::Ticket->new( rt => $rt );

$rt->login( username => $rt_conf->{user}, password => $rt_conf->{pass} );

#use YAML;
#print Dump $config, $state; exit;

my $customers = $config->get('customers');
my $startdate = set_dates($customers);

my @limits = map +{
    attribute  => 'status',
    operator   => '=',
    value      => $_,
    aggregator => 'or',
    },

    # XXX This should be a config option
    qw/ open stalled resolved /;

push @limits,
    {
    attribute => 'last_updated',
    operator  => '>=',
    value     => $startdate->ymd,
    };

my $results = $tickets->search(
    limits  => \@limits,
    orderby => 'id',
);

my $count = $results->count;
print "There are $count results that matched your query\n";

my $iterator = $results->get_iterator;
while ( my $ticket = &$iterator ) {
    my $cust = find_customer_for_ticket( $ticket, $customers );
    if ( !$cust ) {
        warn "No customer found for ticket " . $ticket->id;
        next;
    }

    next if $cust->{no_invoice};
    $cust->{invoice} ||= make_invoice($cust);
    if ( !$cust->{invoice} ) {
        $cust->{no_invoice} = 1;
        say "$cust->{id} has no open invoices [" . $ticket->id . ']';
        next;
    }

    say 'Ticket ' . $ticket->id . " belongs to $cust->{id}";

    my $project = make_project( $ticket, $cust );
    next unless @{ $project->{fees} } || @{ $project->{expenses} };

    foreach my $fee ( @{ $project->{fees} } ) {
        my $hours = hours_for_date( $cust->{invoice}, $fee->{date} );

        my $type  = 'unknown';
        my $count = $fee->{count};
        while ( $type && $count > 0 && $type ne 'default' ) {
            $type = exists $hours->{ $fee->{type} }
                && $hours->{ $fee->{type} } > 0 ? $fee->{type} : 'default';

            next unless exists $hours->{$type} && $hours->{$type} > 0;

            my $discount_time = 0;
            if ( $hours->{$type} > $count ) {
                $hours->{$type} -= $count;
                $discount_time = $count;
            }
            else {
                $discount_time = $hours->{$type};
                $hours->{$type} = 0;
            }

            if ($discount_time) {
                $cust->{invoice}->{discount}->{amount}
                    += round( $discount_time * $fee->{rate} );
                $cust->{invoice}->{discount}->{hours}{$type}
                    += $discount_time;

                $type = '' if $type eq 'default';
                $count -= $discount_time;
                $fee->{detail} .= " $discount_time $type Hours Discounted";
            }
        }
    }

    push @{ $cust->{invoice}->{projects} }, $project;
}

foreach my $cust ( @{$customers} ) {
    my $invoice = $cust->{invoice};
    next unless $invoice && $invoice->{projects} && @{ $invoice->{projects} };

    $invoice->{custid}       = $cust->{id};
    $invoice->{transactions} = [];

    my %transactions;
    foreach my $project ( @{ $invoice->{projects} } ) {
        if ( $project->{transactions} ) {
            %transactions = ( %transactions, %{ $project->{transactions} } );
        }
        my $subtotal = 0;
        foreach my $fee ( @{ $project->{fees} } ) {
            my $amount = round( $fee->{count} * $fee->{rate} );
            $subtotal += $amount;
        }
        foreach my $expense ( @{ $project->{expenses} } ) {
            $subtotal += round( $expense->{amount} );
        }
        $project->{total} = $subtotal;
        $invoice->{total} += $subtotal;
    }
    @{ $invoice->{transactions} } = sort { $a <=> $b } keys %transactions;

    if ( $invoice->{discount} ) {
        my $c = "Included Hours\n";
        if ( $invoice->{discount}{hours} ) {
            foreach my $t ( keys %{ $invoice->{discount}{hours} } ) {
                my $type = $t eq 'default' ? '' : $t;
                $c .= "\n$invoice->{discount}{hours}{$t} $type hour";
                $c .= 's' if $invoice->{discount}{hours}{$t} != 1;
                $c .= "\n";
            }
        }
        $invoice->{discount}{contents} = $c;
        $invoice->{total} -= round( $invoice->{discount}{amount} );
    }

    if ( my $unpaid_invoices = $state->unpaid_invoices( $cust->{id} ) ) {
        my %project = ( title => 'Unpaid Invoices', fees => [], );
        my $past_due = 0;

        foreach my $id ( sort { $a <=> $b } keys %{$unpaid_invoices} ) {
            my $unpaid  = $state->get_invoice($id);
            my $invdate = ymd_to_DateTime( $unpaid->{invdate} );

            next
                if $cust->{duedate}
                    && DateTime->compare( $invdate, $cust->{duedate} ) > 0;

            $past_due += $unpaid_invoices->{$id};
            push @{ $project{fees} },
                {
                id => $id,
                contents =>
                    sprintf( "Invoice %06d from %s", $id, $invdate->ymd ),
                count => 1,
                rate  => $unpaid_invoices->{$id},
                };
        }

        if ($past_due) {
            $invoice->{past_due}  = $past_due;
            $invoice->{total_due} = $invoice->{total} + $invoice->{past_due};

            unshift @{ $invoice->{projects} }, \%project;
        }
    }

    next unless $invoice->{total} > 0 || $invoice->{total_due};

    $invoice->{info} = $config->get('info');
    my $from = $config->get('from');
    $from = get_user($from) if !ref $from;

    $invoice->{id} = $state->next_invoice_id;
    $invoice->{file} = sprintf 'invoice_%06d.pdf', $invoice->{id};

    $invoice->{organization} = $from->{organization} || $from->{name};
    $invoice->{from} = make_address($from);
    $invoice->{to}   = make_address( $cust->{address} || $cust->{id} );
    $invoice->{logo} = $config->get('logo');

    $state->add_invoice($invoice);

    foreach my $key (qw/ start end /) {
        if ( exists $invoice->{$key} ) {
            $invoice->{$key} = $invoice->{$key}->strftime('%B %d, %Y');
        }
    }

    my $invoice_dir = $config->get('invoice_dir');
    File::Path::make_path($invoice_dir);
    my $file = join '/', $invoice_dir, $invoice->{file};

    my $tt = Template->new( INCLUDE_PATH => $config->get('template_dir'), )
        || die $Template::ERROR, "\n";

    $tt->process( $config->get('invoice_template'), $invoice, $file )
        or die $tt->error . "\n";

    printf "Generated %s for %s: \$%.02f\n", $invoice->{file}, $cust->{id},
        $invoice->{total};

}

$state->save;

sub round {
    my ($amount) = @_;

    #$amount =~ s/\.\d\d\K.*$//;
    #return $amount;
    return sprintf "%.02f", $amount;
}

sub find_customer_for_ticket {
    my ( $ticket, $customers ) = @_;

    foreach my $cust ( @{$customers} ) {
        next unless $cust->{match};
        foreach my $m ( @{ $cust->{match} } ) {
            my $type = $m->{type};
            my $match
                = exists $m->{$type}
                ? lc( $m->{$type} )
                : qr/\Q$m->{regex}\E/;
            my $thing = [ map {lc} $ticket->$type ];

            if ( !$match ) {
                warn "Invalid match!";
                next;
            }
            return $cust if ( $match ~~ $thing );
        }
    }

    # Fake customer if we didn't find one
    my $cust = $config->new_customer;

    ( $cust->{id} ) = $ticket->requestors;
    return unless $cust->{id};
    push @{$customers}, $cust;

    $cust->{match} = [
        {   type  => 'requestors',
            regex => $cust->{id},
        }
    ];

    set_cust_dates($cust);
    return $cust;
}

sub get_user {
    my ($id) = @_;

    state %users;
    return $users{$id} if $users{$id};

    my %map = (
        address_one   => 'addr1',
        address_two   => 'addr2',
        email_address => 'email',
        real_name     => 'name',
        name          => 'username',
    );

    my $users = RT::Client::REST::User->new( rt => $rt, id => $id );
    $users->retrieve;

    my %user;
    foreach my $m ( keys %{ $users->_attributes } ) {
        next unless $users->can($m);

        my $v = $users->$m;
        next unless $v;

        $m = $map{$m} if exists $map{$m};

        $user{$m} = $v;
    }

    $users{$id} = \%user;
    return \%user;
}

sub make_invoice {
    my ($cust) = @_;

    return if $cust->{no_invoice};
    return unless $cust->{billstart};

    my %invoice
        = ( end => $cust->{billend}->clone->subtract( seconds => 1 ) );
    $invoice{start} = $cust->{startinvoicedate}->clone
        if $cust->{startinvoicedate};

    return if $invoice{start} && $invoice{start} > $invoice{end};

    if ( $cust->{base_rate} ) {
        my ( $project, $hours ) = make_base_project($cust);

        if ( @{ $project->{fees} } ) {
            $invoice{end}   = $project->{end};
            $invoice{hours} = $hours;
            push @{ $invoice{projects} }, $project;
        }
    }
    elsif ( $cust->{hours} ) {
        $invoice{hours} = [
            {   end   => $invoice{end}->clone,
                hours => $cust->{hours},
            }
        ];
    }

    return \%invoice;
}

sub make_base_project {
    my ($cust) = @_;

    my $date    = $cust->{billstart}->clone;
    my $billend = $cust->{billend}->clone;
    my ($freq)  = get_billing_frequency($cust);

    my $title
        = $cust->{frequency} == 1
        ? ucfirst( $cust->{per} . 'ly' )
        : $freq . ' ' . ucfirst( $cust->{per} );
    $title .= ' Retainer';

    my %project = ( title => $title, start => $date->clone, fees => [], );
    my @hours;

    while ( $date < $billend ) {
        my $start = $date->clone;

        $date->add($freq);

        my $end = $date > $billend ? $billend->clone : $date->clone;
        $end->subtract( seconds => 1 );

        $project{end} = $end->clone;

        push @{ $project{fees} },
            {
            count    => 1,
            rate     => $cust->{base_rate},
            contents => $start->ymd . ' to ' . $end->ymd,
            };

        push @hours,
            {
            start => $start->clone,
            end   => $end->clone,
            hours => { %{ $cust->{hours} } },
            };
    }

    return \%project, \@hours;
}

sub make_address {
    my ($addr) = @_;
    my @adr;

    $addr = get_user($addr) unless ref $addr;

    if ( $addr->{organization} ) {
        push @adr, $addr->{organization};
    }
    elsif ( $addr->{name} && !$addr->{attn} ) {
        push @adr, $addr->{name};
    }

    if (   ( $addr->{addr1} || $addr->{addr2} )
        && $addr->{city}
        && $addr->{state}
        && $addr->{zip} )
    {
        push @adr, $addr->{attn}  if $addr->{attn};
        push @adr, $addr->{addr1} if $addr->{addr1};
        push @adr, $addr->{addr2} if $addr->{addr2};
        push @adr,
            $addr->{city} . ', ' . $addr->{state} . '  ' . $addr->{zip};
    }
    else {
        push @adr, $addr->{email} if $addr->{email};
    }

    return join "\n\n", @adr;
}

sub make_project {
    my ( $ticket, $cust ) = @_;

    my %project = (
        id     => $ticket->id,
        queue  => $ticket->queue,
        owner  => $ticket->owner,
        title  => $ticket->subject,
        detail => 'Ticket: '
            . $ticket->id
            . ' Status: '
            . $ticket->status
            . ' Requestors: '
            . join( ', ', $ticket->requestors ),
        fees     => [],
        expenses => [],
    );

    my $txns = $ticket->transactions( type => [qw(Comment Correspond)] );
    my $txn_i = $txns->get_iterator;
    while ( my $txn = $txn_i->() ) {
        next if $state->txn_is_invoiced( $txn->id );

        if ( my $expense = make_expense( $txn, $ticket ) ) {
            push @{ $project{expenses} }, $expense;
            $project{transactions}{ $txn->id } = 1;
        }

        next unless $txn->time_taken;

        my $fee = make_fee( $txn, $cust->{rates}, $ticket );

        if ( !( $fee->{rate} && $fee->{count} ) ) {
            warn "Invalid Fee, no rate or count";
            next;
        }

        my $invoice = $cust->{invoice};
        if ( $invoice->{start} && $invoice->{start} > $fee->{date} ) {
            warn "Ticket "
                . $ticket->id
                . " has uninvoiced Transaction "
                . $txn->id . "\n";
            next;
        }
        next if $invoice->{end} < $fee->{date};

        push @{ $project{fees} }, $fee;
        $project{transactions}{ $txn->id } = 1;
    }

    return \%project;
}

sub make_fee {
    my ( $txn, $rates, $ticket ) = @_;

    # XXX Only need $ticket for the alternate subject

    my $work_time = sprintf "%.03f", $txn->time_taken / 60;
    my $work_type = $txn->cf('WorkType');

    if ( $work_type =~ s/\s*Onsite//i ) {

        # XXX Do something special for onsite activities
    }

    $work_type =~ s/^\s+|\s+$//g;
    $work_type ||= 'Normal';

    my %fee = (
        id       => $txn->id,
        contents => $txn->created . ' ('
            . $txn->id . ')' . "\n\n"
            . ( $txn->data || $ticket->subject ),
        count => $work_time,
        type  => $work_type,
        date  => ymd_to_DateTime( $txn->created ),
        rate  => $rates->{$work_type} || $rates->{default} || 0,
    );

    if ( $work_type && $work_type ne 'Normal' ) {
        $fee{detail} = $work_type . ' rate';
    }

    return \%fee;
}

sub make_expense {
    my ( $txn, $ticket ) = @_;

    my $amount = $txn->cf('ExpenseAmount') or return;

    my %expense = (
        id       => $txn->id,
        contents => $txn->created . ' ('
            . $txn->id . ')' . "\n\n"
            . ( $txn->data || $ticket->subject ),
        amount => $amount,
        date   => ymd_to_DateTime( $txn->created ),

        # detail => ???,
    );

    return \%expense;
}

sub hours_for_date {
    my ( $invoice, $date ) = @_;

    my $hours = {};
    if ( $invoice->{hours} ) {
        foreach my $h ( @{ $invoice->{hours} } ) {
            next if $h->{start} && $h->{start} > $date;
            next if $h->{end} < $date;

            $hours = $h->{hours};
            last;
        }
    }
    return $hours;
}

sub ymd_to_DateTime {
    my ($ymd) = @_;
    my ( $date, $time ) = split /[\sT]/, $ymd;
    my ( $year, $month, $day ) = split '-', $date;
    my ( $hour, $minute, $second ) = split ':', $time if $time;

    return DateTime->new(
        year      => $year,
        month     => $month,
        day       => $day,
        hour      => $hour || 0,
        minute    => $minute || 0,
        second    => $second || 0,
        time_zone => 'local',
    );
}

sub get_billing_frequency {
    my ($cust) = @_;
    my $per  = $cust->{per}       || 'week';
    my $freq = $cust->{frequency} || 1;

    my $day_method;
    given ($per) {
        when ('week')  { $per = 'weeks';  $day_method = 'dow' }
        when ('month') { $per = 'months'; $day_method = 'day' }
        default { die "Unknown per [$per]\n" }
    }

    return DateTime::Duration->new( $per => $freq ), $day_method;
}

sub set_dates {
    my ($customers) = @_;

    my $newest_invoice;
    my $max_duration;

    foreach my $cust ( @{$customers} ) {
        set_cust_dates($cust);

        my ($freq) = get_billing_frequency($cust);
        $max_duration = $freq
            if !$max_duration
                || DateTime::Duration->compare( $freq, $max_duration ) > 0;

        if ( $cust->{startinvoicedate} ) {
            my $date = $cust->{startinvoicedate}->clone;
            $newest_invoice = $date->clone
                if !$newest_invoice || $newest_invoice < $date;
        }
    }

    return $newest_invoice->clone->subtract($max_duration)
        ->subtract( days => 1 );
}

sub set_cust_dates {
    my ($cust) = @_;

    my $day = $cust->{day} || 0;
    my ( $freq, $day_method ) = get_billing_frequency($cust);

    my $end = DateTime->now( time_zone => 'local' )
        ->set( hour => 0, minute => 0, second => 0 );

    my $start = $end->clone->subtract($freq);

    # XXX This is helpful, but monthly and billday > 28 == !!!
    $end->subtract( days => 1 ) while $day && $end->$day_method != $day;

    my $lastinvoice = $state->last_invoice( $cust->{id} );
    if ( $lastinvoice && $lastinvoice->{end} ) {
        $start = ymd_to_DateTime( $lastinvoice->{end} )->add( days => 1 );
        $cust->{startinvoicedate} = $start->clone;
    }

    $cust->{duedate}
        = $cust->{net}
        ? DateTime->now->subtract( days => $cust->{net} )
        : 0;

    $cust->{no_invoice} = 1 if $start->clone->add($freq) > $end;
    $cust->{billend}    = $end;
    $cust->{billstart}  = $start;
}