Return to update_trango.pl CVS log

Up to [local] / trango / Net-Telnet-Trango / scripts

better logging

#!/usr/bin/perl
# $RedRiver: update_trango.pl,v 1.4 2005/11/16 21:13:39 andrew Exp $
########################################################################
# update_trango.pl *** Updates trango foxes with a new firmware
# 
# 2005.11.15 #*#*# andrew fresh <andrew@mad-techies.org>
########################################################################
use strict;
use warnings;

use Net::Telnet;
use Net::TFTP;
use Fcntl ':flock'; # import LOCK_* constants
#use YAML;


my $config_file = shift || 'update_trango.conf';
my $conf = read_conf($config_file);

my $max_tries = 1;

my $log_file =  GetLogName('UT');
use constant LOG_SAVE => 1;

my $MYLOG;  # file handle for logging so we don't have to close and open it all the time
END {
  if ($MYLOG) {
    mylog("Closing log ($log_file)");
    close $MYLOG;
  }
}








foreach my $fox (@{ $conf->{'ips'} }) {
  mylog("Updating: $fox", LOG_SAVE);

  ## Connect and login.
  my $host = new Net::Telnet (Timeout => 5,
                              Prompt => '/#> *$/');
  mylog("Connecting to $fox");
  $host->open($fox);
  $host->dump_log('dump.log');

  ## Login to remote host.
  $host->waitfor(
    -match => '/password: ?$/i',
    -errmode => "return",
  ) or die "problem connecting to host ($fox): ", $host->lastline;

  my $login_banner = $host->lastline;
  my ($type, $version) = $login_banner =~ 
    /Welcome to Trango Broadband Wireless (\w+)-(.+)$/i;

  if ($type ne $conf->{'type'}) {
    mylog("Wrong type of unit ('$type' should be '$conf->{'type'}')", LOG_SAVE);
    $host->close;
    next;
  }

  if ($version eq $conf->{'ver'}) {
    mylog("Already up to date with firmware version '$version'", LOG_SAVE);
    $host->close;
    next;
  }

  mylog("Logging in");
  $host->print($conf->{'password'});
  unless ($host->waitfor(
    -match => $host->prompt,
    -errmode => "return",
  ) ) {
    mylog("login ($fox) failed: " . $host->lastline);
    next;
  }


  mylog("Sending commands");
  ## Send commands
  if ( upload($host, $fox, $conf->{'file_name'}) ) {
    mylog("Rebooting");
    $host->print("reboot\n");
    $host->getline;
  } else {
    mylog("Exiting");
    $host->print("exit\n");
    $host->getline;
  }
  $host->close;
  mylog("", LOG_SAVE);
}

sub upload
{
  my $host = shift;
  my $fox  = shift;
  my $file = shift;

  mylog("Getting current version");
  my $ver = get_ver($host);

  if (
    $ver->{'Firmware Version'}  eq $conf->{'ver'} && 
    $ver->{'Firmware Checksum'} eq $conf->{'cksum'}
  ) {
    mylog("Already updated!", LOG_SAVE);
    return 1;
  }

  my $try = 0;
  while (1) {
    if ($try >= $max_tries) {
      mylog("Couldn't update in $max_tries tries!");
      return undef;
    }
    $try++;

    #sysinfo($host);
    
    mylog("Enabling TFTPd");
    enable_tftpd($host) || die "Couldn't enable tftpd";

    mylog("Uploading file ($file)");
    # use tftp to push the file up
    my $tftp = Net::TFTP->new($fox, Mode => 'octet');

    $tftp->put($file, $file) 
      or die "Error uploading: " . $tftp->error;

    # waitfor some sort of output
    # make sure it says 'Success.' otherwise error
    #print "LAST: " . $host->lastline;
    #my @lines = $host->getlines;
    #print Dump \@lines;
    
    mylog("Checking upload ($conf->{'file_cksum'})");
    my $results = check_tftpd($host);
    # check the 'File Length' against ???
    if ( $results->{'File Checksum'} ne $conf->{'file_cksum'}) {
      mylog("File checksum does not match config file!", LOG_SAVE);
      next;
    } 
    mylog("File checksum ($results->{'File Checksum'}) " . 
          "matches ($conf->{'file_cksum'})");

    if ($results->{'File Length'}   !~ /^$conf->{'file_size'} bytes/) {
      mylog("File length does not match config file!", LOG_SAVE);
      next;
    }
    mylog("File length ($results->{'File Length'}) " . 
          "matches ($conf->{'file_size'})");

    if ( uc($results->{'File Name'}) ne uc($conf->{'file_name'}) ) {
      mylog("File name does not match config file!", LOG_SAVE);
      next;
    }
    mylog("File name ($results->{'File Name'}) " . 
          "matches ($conf->{'file_name'})");

    mylog("Updating flash (new checksum '$conf->{'cksum'}')");
    $results = updateflash(
      $host, $ver->{'Firmware Checksum'}, $conf->{'cksum'}
    ) or die "Couldn't update flash: " . $host->lastline;
    unless (
      defined $results->{'Checksum'} && 
      $results->{'Checksum'} eq $conf->{'cksum'}
    ) {
      mylog("Saved checksum does not match config file!", LOG_SAVE);
      next;
    }
    mylog("Uploaded checksum ($results->{'Checksum'}) " . 
          "matches ($conf->{'cksum'})");
    
    mylog("Successfully updated!", LOG_SAVE);
    return 1;
  }
}

sub get_ver
{
  my $host = shift;
  return cmd($host, 'ver');
}

sub enable_tftpd
{
  my $host = shift;

  my $vals = cmd($host, 'tftpd on', 'Success.');

  if ($vals->{'Tftpd'} eq 'listen') {
    return $vals;
  } else {
    return undef;
  }
}

sub check_tftpd
{
  my $host = shift;
  return cmd($host, 'tftpd', 'Success.');
}

sub sysinfo
{
  my $host = shift;
  return cmd($host, 'sysinfo', 'Success.');
}

sub updateflash
{
  my $host = shift;
  my $old = shift;
  my $new = shift;

  return undef unless $new;

  return cmd($host, "updateflash mainimage $old $new", 'Success.', 90);
}

sub cmd
{
  my $host   = shift;
  my $string = shift;
  my $expect_last = shift;
  my $timeout = shift || 5;

  my @lines = $host->cmd(String => $string, Timeout => $timeout);

  my $vals = decode_lines(@lines);

  my $last = $host->lastline;

  unless ($expect_last) {
    return $vals;
  }

  if ($last =~ /$expect_last$/) {
    return $vals;
  } else {
    warn "Error with command ($string): $last";
    return undef;
  }
}

sub decode_lines
{
  my @lines = @_;

  my %conf;

  my $key = '';
  my $val = '';
  my $in_key = 0;
  my $in_val = 0;

  foreach my $line (@lines) {
    my @chars = split //, $line;

    my $last_key = '';
    foreach my $c (@chars) {

      if ($c eq '[' || $c eq "\r" || $c eq "\n") {
        if ($c eq '[') {
          $in_key = 1;
          $in_val = 0;
        } else {
          $in_key = 0;
          $in_val = 0;
        }

        if ($key) {
          $key =~ s/^\s+//;
          $key =~ s/\s+$//;

          $val =~ s/^\s+//;
          $val =~ s/\s+$//;

          if ($key eq 'Checksum' && $last_key) {
            # Special case for these bastids.
            my $new = $last_key;
            $new =~ s/\s+\S+$//;
            $key = $new . " " . $key;
          }

          $last_key = $key;
          $conf{$key} = $val;
          $key = '';
          $val = '';
        }

      } elsif ($c eq ']') {
        $in_val = 1;
        $in_key = 0;
        $c = shift @chars;

      } elsif ($in_key) {
        $key .= $c;

      } elsif ($in_val) {
        $val .= $c;
      }
    }
  }
  #print Dump \%conf;

  if (%conf) {
    return \%conf;
  } else {
    return \@lines;
  }
}

sub read_conf
{
  my $file = shift;
  my %conf;
  my $in_ip_list = 0;
  open my $fh, $file or die "Couldn't open file $file: $!";
  while (<$fh>) {
    chomp;
    next if /^#/;
    next if /^$/;
    if ($in_ip_list) {
      push @{ $conf{'ips'} }, $_;
    } else {
      my ($key, $val) = split /\s+/, $_, 2;

      if (lc($key) eq 'ips') {
        $in_ip_list = 1;
        next;
      }

      $conf{ lc($key) } = $val;
    }
  }
  close $fh;

  #print Dump \%conf;
  foreach (
    'password', 
    'file_name', 'file_size', 'file_cksum', 
    'ver', 'cksum', 'ips',
  ) {
    die "No $_ specified in config file!"
      if (not exists $conf{$_});
  }

  return \%conf;
}

sub mylog
{
  my $thing = shift;
  chomp $thing;
  my $save = shift;

  print $thing, "\n";

  if (defined $save && $save == LOG_SAVE) {
    unless ($MYLOG) {
      open ($MYLOG, '>>', $log_file) 
        or die "Couldn't open logfile!\n";
      my $ofh = select $MYLOG;
      $|=1;
      select $ofh;
      mylog("Opened log ($log_file)");
    }

    flock($MYLOG, LOCK_EX);
    print $MYLOG (scalar gmtime), "\t", $thing, "\n" 
      or die "Couldn't print to MYLOG: $!";
    flock($MYLOG, LOCK_UN);
  }
}

sub GetLogName
{
  my $prefix  = shift || die "Invalid prefix passed for log";

  my $logdate = GetLogDate();
  my $logver  = 0;
  my $logname;

  do {
    $logname = $prefix . $logdate . sprintf("%02d", $logver) . '.log';
    $logver++;
  } until (not -e $logname);

  return $logname;
}

sub GetLogDate
{
  my ($sec,$min,$hour,$mday,$mon,$year,,,) = localtime();

  $mon++;
  $year += 1900;

  if ($min  < 10) { $min  = "0$min"  }
  if ($sec  < 10) { $sec  = "0$sec"  }
  if ($hour < 10) { $hour = "0$hour" }
  if ($mday < 10) { $mday = "0$mday" }
  if ($mon  < 10) { $mon  = "0$mon"  }

  my $time = $year . $mon . $mday;

  return $time;
}