Return to list.t CVS log

Up to [local] / todotxt / Text-Todo-REST-API / t / GET

an entry has more metadata now

#===============================================================================
#
#         FILE:  GET/list.t
#
#  DESCRIPTION:  Test Text::Todo::REST::API
#
#       AUTHOR:  Andrew Fresh (AAF), andrew@cpan.org
#      COMPANY:  Red River Communications
#      CREATED:  01/07/10 19:11
#     REVISION:  $AFresh1: list.t,v 1.9 2010/02/26 05:24:13 andrew Exp $
#===============================================================================

use strict;
use warnings;

use Test::More tests => 59;

my $api_class;
my $class;

BEGIN {
    $api_class = 'Text::Todo::REST::API';
    $class     = 'Text::Todo::REST::API::Actions::GET';

    use_ok( $api_class, "use $api_class" );
    use_ok( $class,     "use $class" );
}

diag("Testing GET list $class $Text::Todo::REST::API::Actions::GET::VERSION");

my $api = new_ok( $api_class, [ { todo_dir => 't/lists' } ] );
my $action = new_ok($class);

my $list_should_be = [
    {   'text' => '(A) entry 1 @one +uno',
        'md5'  => '931e0831c31a70928b29de55778dc294',
        'line' => 1,
        'done' => undef,
    },
    {   'text' => 'entry 2 @two +dos',
        'md5'  => 'b38dde8029c047e81379d9de581a6251',
        'line' => 2,
        'done' => undef,
    },
    {   'text' => '',
        'md5'  => 'd41d8cd98f00b204e9800998ecf8427e',
        'line' => 3,
        'done' => undef,
    },
    {   'text' => 'x completed entry 4',
        'md5'  => '8de0a2b65a50d5e30e84ad48af46fa78',
        'line' => 4,
        'done' => 'x',
    },
    {   'text' => '(B) entry 5 is priority',
        'md5'  => 'c1692dfbf3b5829b6bce44b1a1614980',
        'line' => 5,
        'done' => undef,
    },
    {   'text' => 'entry 6 +delete',
        'md5'  => 'e1f6bf867f75aa019063782554407d02',
        'line' => 6,
        'done' => undef,
    }
];

my $list;
ok( $list = $action->get_list( $api->_todo ), 'get_list' );
is( scalar @{$list}, 6, 'list is right length' );
is_deeply( $list, $list_should_be, 'check that we got the right list' );

foreach my $arg (
    { list => undef, action => 'list', args => [] },

    'todo_file', '/todo_file/',
    { path => '/todo_file/' },
    { list => 'todo_file', action => 'list', args => [] },

    'todo', '/todo/',
    { path => '/todo/' },
    { list => 'todo', action => 'list', args => [] },

    'todo.txt', '/todo.txt/',
    { path => '/todo.txt/' },
    { list => 'todo.txt', action => 'list', args => [] },
    )
{
    my $response;
    ok( $response = $api->GET($arg), "GET($arg)" );
    my $list;
    ok( $list = $response->data, 'Get response data' );
    is( scalar @{$list}, 6, 'list is right length' );
    is_deeply( $list, $list_should_be, 'check that we got the right list' );
}