File: [local] / openbsd / update_openbsd / post_dmesg_to_nycbug (download)
Revision 1.5, Tue Mar 3 18:56:08 2015 UTC (9 years, 3 months ago) by andrew
Branch: MAIN
Changes since 1.4: +6 -2 lines
Better detect a nickname/email that aren't mine
because people apparently can't change that.
|
#!/usr/bin/perl
use strict;
use warnings;
use feature 'say';
use Sys::Hostname;
use HTTP::Tiny;
# This script posts your OpenBSD dmesg to the NYC*BUG dmesg archive.
my $nickname = "$ENV{USER}";
my $email = "$ENV{USER}\@" . hostname();
my @sysctls = (
[qw( hw.vendor hw.product hw.version )],
[qw( hw.model )],
);
my $description = "@ARGV";
while ( @sysctls and not $description ) {
my @s = @{ shift @sysctls };
open my $de, '-|', qw( sysctl -n ), @s or die $!;
$description = join ' ', split /\s+/s,
do { local $/ = undef; readline $de };
close $de or die $!;
}
print "About to post '$description', OK? ";
readline STDIN;
open my $dm, '<', '/var/run/dmesg.boot' or die $!;
my $dmesg = do { local $/ = undef; readline $dm };
close $dm;
# Remove leftover cruft from previous boots
$dmesg =~ s/^.*\n(OpenBSD )/$1/s;
my $res = HTTP::Tiny->new->post_form(
'http://www.nycbug.org/index.cgi',
{ action => 'dmesgd',
do => 'addd',
nickname => $nickname,
email => $email,
description => $description,
dmesg => $dmesg,
}
);
say $res->{success}
? 'Sent dmesg'
: "Unable to send dmesg: $res->{status} $res->{reason}";