Return to check_bioctl CVS log

Up to [local] / nagios / check_bioctl

make perlcritic happier

#!/usr/bin/perl -T
# $RedRiver: check_bioctl,v 1.10 2009/11/12 18:54:38 andrew Exp $
########################################################################
# check_bioctl *** A nagios check for OpenBSD bioctl
#
# 2006.07.26 #*#*# andrew fresh <andrew@afresh1.com>
########################################################################
use strict;
use warnings;

use 5.010;

local %ENV = ();

my $NAGIOS_OUTPUT => 1;

my $License = <<'EOL';
Copyright (c) 2009 Andrew Fresh <andrew@afresh1.com>
Permission to use, copy, modify, and distribute this software for any
purpose with or without fee is hereby granted, provided that the above
copyright notice and this permission notice appear in all copies.

THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
EOL

my $PROGNAME = 'check_bioctl';
my $BIOCTL   = '/sbin/bioctl';

use POSIX;
my $PREFIX;

BEGIN {
    ## no critic 'warnings'
    no warnings 'uninitialized';
    $PREFIX = "${PREFIX}" || '/usr/local';    # Magic for OpenBSD ports tree
}
use lib $PREFIX . '/libexec/nagios';
use utils qw($TIMEOUT %ERRORS &support);

$SIG{'ALRM'} = sub {
    say "ERROR: $PROGNAME timeout";
    exit $ERRORS{'UNKNOWN'};
};
alarm($TIMEOUT);

use Getopt::Long;
Getopt::Long::Configure('bundling');

# This maps the status we get from bioctl to something nagios can use
my %Status_Map = (
    Online      => 'OK',
    Offline     => 'CRITICAL',
    Degraded    => 'CRITICAL',
    Failed      => 'CRITICAL',
    Building    => 'WARNING',
    Rebuild     => 'WARNING',
    'Hot spare' => 'OK',
    Unused      => 'OK',
    Scrubbing   => 'WARNING',
    Invalid     => 'CRITICAL',
);

my $state = 'UNKNOWN';    # tells whether the it is warning, critical, or OK
my @devices;
my $opt_h;
my $opt_V;

#Option checking
my $status = GetOptions(
    "version|V"  => \$opt_V,
    "help|h"     => \$opt_h,
    "device|d=s" => \@devices,
);

if ( $status == 0 ) {
    print_help();
    exit $ERRORS{'OK'};
}

if ($opt_V) {
    print_revision( $PROGNAME, '$Revision: 1.11 $ ' );
    exit $ERRORS{'OK'};
}

if ( $opt_h || !@devices ) {
    print_help();
    exit $ERRORS{'OK'};
}

my %VOLUMES = read_bioctl( \@devices );
my %STATES  = check_status( \%VOLUMES );

my $have_results = 0;
$state = 'OK';
foreach my $error ( sort { $ERRORS{$b} <=> $ERRORS{$a} } keys %ERRORS ) {
    if ( exists $STATES{$error} ) {
        $have_results++;
        $state = $error if $ERRORS{$state} < $ERRORS{$error};

        if ($NAGIOS_OUTPUT) {
            print "$error (" . scalar( @{ $STATES{$error} } ) . ")";
            if ( $error ne 'OK' ) {
                print '<br>';
                print map {" - $_<br>"} @{ $STATES{$error} };
            }
        }
        else {
            print "$error (" . scalar( @{ $STATES{$error} } ) . "):\n";
            print map {"    $_\n"} @{ $STATES{$error} };
        }
    }
}
if ( $have_results == 0 ) {
    print "No results found\n";
}
exit $ERRORS{$state};

sub read_bioctl {
    my ($devices) = @_;
    my %volumes;

    foreach my $d ( @{$devices} ) {
        open my $bioctl, q{-|}, $BIOCTL, $d
            or die "Couldn't open bioctl: $!\n";
        while ( my $line = <$bioctl> ) {
            my ( $i, $item ) = parse_bioctl_line($line);
            $volumes{$d}{$i} = $item;
        }
        ## no critic 'die'
        close $bioctl
            or die $!
            ? "Error closing bioctl pipe: $!\n"
            : "Exit status $? from bioctl \n";
    }

    foreach my $d ( keys %volumes ) {
        foreach my $i ( keys %{ $volumes{$d} } ) {
            my $item = $volumes{$d}{$i};
            if ( $item->{device} =~ /^\d+:\d+/xms ) {
                $item->{'volume'} = $volumes{$d}{ $i->{volume_id} };
            }
        }
    }

    return %volumes;
}

sub parse_bioctl_line {
    my ($line) = @_;
    state $vid;
    chomp $line;

    # Do these by columns cuZ that is the easiest for now
    my @o = unpack( "A6 A1 A11 A15 A7 A9 A*", $line );
    next if $o[0] eq 'Volume';

    foreach (@o) {
        s/^\s+//xms;
        s/\s+$//xms;
    }

    my ( $controller, $id, $status, $size, $dev, $details, $name ) = @o;
    my $index = $id;
    if ($controller) {
        $vid = $id;
    }
    else {
        $index = "$vid.$id";
    }

    my %item = (
        type       => 'volume',
        controller => $controller,
        id         => $id,
        status     => $status,
        size       => $size,
        device     => $dev,
        details    => $details,
        name       => $name,
        volume_id  => $vid,
    );

    return $index, \%item;
}

sub check_status {
    my ($volumes) = @_;

    my %states;
    foreach my $device ( sort keys %{$volumes} ) {
        foreach my $index ( sort keys %{ $volumes->{$device} } ) {
            my $cur_volume = $volumes->{$device}->{$index};
            my $cur_state  = $Status_Map{ $cur_volume->{'status'} }
                || 'UNKNOWN';

            if ( $cur_volume->{'device'} =~ /^\d+:\d/xms ) {
                push @{ $states{$cur_state} },
                    sprintf(
                    "%5s %-7s %-11s %s",
                    $cur_volume->{'volume'}{'controller'},
                    $cur_volume->{'device'},
                    $cur_volume->{'status'},
                    $cur_volume->{'name'}
                    );
            }
            else {
                push @{ $states{$cur_state} },
                    sprintf( "%5s %-7s %s",
                    $cur_volume->{'controller'},
                    $cur_volume->{'device'},
                    $cur_volume->{'status'} );
            }
        }
    }
    return %states;
}

sub print_help {
    print <<"EOL";
$PROGNAME plugin for Nagios monitors bioctl on OpenBSD
    $PROGNAME -d <device> [ -d <device2> [ -d ... ] ]

Usage:
    -d, --device=DEVICE
        DEVICE to check.  Can be any device that bioctl(8) accepts
    -h (--help)       usage help
	-V (--version)    version information

EOL

    print_revision( $PROGNAME, '$Revision: 1.11 $' );

    print $License;

    return 1;
}

sub print_revision {
    my ( $prog, $rev ) = @_;
    $rev =~ s/^\D+([\d\.]+)\D+$/v$1/xms;

    say "$prog $rev";

    return 1;
}