Return to rt_invoices.pl CVS log

Up to [local] / RT / Invoicing

add an invoice_dir to store the configs in

#!/usr/bin/perl
# $AFresh1: rt_invoices.pl,v 1.18 2011/03/22 04:55:27 andrew Exp $
########################################################################
# Copyright (c) 2011 Andrew Fresh <andrew@afresh1.com>
#
# Permission to use, copy, modify, and distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
########################################################################
use strict;
use warnings;

use 5.010;

use Template;
use RT::Client::REST;
use RT::Client::REST::Ticket;
use RT::Client::REST::User;

use File::Path;
use DateTime;

my $config = RTI::Config->new();
my $state  = RTI::State->new( $config->get('state') );

my $rt_conf = $config->get('rt');
my $rt      = RT::Client::REST->new(
    server  => $rt_conf->{server},
    timeout => $rt_conf->{timeout},
);
my $tickets = RT::Client::REST::Ticket->new( rt => $rt );

$rt->login( username => $rt_conf->{user}, password => $rt_conf->{pass} );

#print Dump $config, $state; exit;

my $startdate;

my $customers = $config->get('customers');
while ( my ( $custid, $cust ) = each %{$customers} ) {
    $cust->{id} = $custid;

    if ( my $invoice = make_invoice($cust) ) {
        $cust->{invoice} = $invoice;
    }
}

my @limits = map +{
    attribute  => 'status',
    operator   => '=',
    value      => $_,
    aggregator => 'or',
    },

    # XXX This should be a config option
    qw/ open stalled resolved /;

if ($startdate) {
    push @limits,
        {
        attribute => 'last_updated',
        operator  => '>=',
        value     => $startdate->ymd,
        };
}

my $results = $tickets->search(
    limits  => \@limits,
    orderby => 'id',
);

my $count = $results->count;
print "There are $count results that matched your query\n";

my $iterator = $results->get_iterator;
while ( my $ticket = &$iterator ) {
    my $cust = find_customer_for_ticket( $customers, $ticket );
    if ( !$cust ) {
        warn "No customer found for ticket " . $ticket->id;
        next;
    }
    if ( !$cust->{invoice} ) {

        #say "Customer has no open invoices for ticket " . $ticket->id;
        next;
    }
    my $invoice = $cust->{invoice};

    my $project = make_project( $ticket, $cust );
    next unless @{ $project->{fees} } || @{ $project->{expenses} };

    foreach my $fee ( @{ $project->{fees} } ) {
        my $hours = hours_for_date( $invoice, $fee->{date} );

        my $h_type
            = exists $hours->{ $fee->{type} }
            ? $fee->{type}
            : 'default';

        next unless exists $hours->{$h_type} && $hours->{$h_type} > 0;

        my $discount_time = 0;
        if ( $hours->{$h_type} > $fee->{count} ) {
            $hours->{$h_type} -= $fee->{count};
            $discount_time = $fee->{count};
        }
        else {
            $discount_time = $hours->{$h_type};
            $hours->{$h_type} = 0;
        }

        if ($discount_time) {
            $invoice->{discount}{amount}
                += round( $discount_time * $fee->{rate} );
            $invoice->{discount}{hours}{$h_type} += $discount_time;

            $h_type = '' if $h_type eq 'default';
            $fee->{detail} = "$discount_time $h_type Hours Discounted";
        }
    }

    push @{ $invoice->{projects} }, $project;
}

while ( my ( $custid, $cust ) = each %{$customers} ) {
    my $invoice = $cust->{invoice};
    next unless $invoice->{projects} && @{ $invoice->{projects} };

    my %li = ( custid => $custid, invdate => DateTime->now->ymd, );

    foreach my $project ( @{ $invoice->{projects} } ) {
        if ( $project->{transactions} ) {
            push @{ $li{transactions} }, @{ $project->{transactions} };
        }
        my $subtotal = 0;
        foreach my $fee ( @{ $project->{fees} } ) {
            my $amount = round( $fee->{count} * $fee->{rate} );
            $subtotal += $amount;
        }
        foreach my $expense ( @{ $project->{expenses} } ) {
            $subtotal += round( $expense->{amount} );
        }
        $project->{total} = $subtotal;
        $invoice->{total} += $subtotal;
    }

    if ( $invoice->{discount} ) {
        my $c = "Included Hours\n";
        if ( $invoice->{discount}{hours} ) {
            foreach my $t ( keys %{ $invoice->{discount}{hours} } ) {
                $c .= "\n$invoice->{discount}{hours}{$t} $t hour";
                $c .= 's' if $invoice->{discount}{hours}{$t} != 1;
                $c .= "\n";
            }
        }
        $invoice->{discount}{contents} = $c;
        $invoice->{total} -= round( $invoice->{discount}{amount} );
    }

    if ( $invoice->{past_due} ) {
        $invoice->{total_due} = $invoice->{total} + $invoice->{past_due};
    }

    next unless $invoice->{total} > 0 || $invoice->{total_due};

    $invoice->{info} = $config->get('info');
    $invoice->{from} = make_address( $config->get('from') );
    $invoice->{to}   = make_address( $cust->{address} || $custid );

    $state->{lastinvoice}++;
    $invoice->{id} = $state->{lastinvoice};
    $invoice->{file} = sprintf 'invoice_%06d.pdf', $state->{lastinvoice};

    foreach my $k (qw/ file transactions start end total past_due total_due /)
    {
        my $v;
        if    ( $invoice->{$k} ) { $v = $invoice->{$k} }
        elsif ( $cust->{$k} )    { $v = $cust->{$k} }

        if ( defined $v && length $v ) {
            if ( ref $v eq 'DateTime' ) {
                $li{$k} = $v->ymd;
            }
            else {
                $li{$k} = $v;
            }
        }
    }
    $state->{invoice}->{ $li{end} }{ $invoice->{id} } = \%li;

    foreach my $key (qw/ start end /) {
        if ( exists $invoice->{$key} ) {
            $invoice->{$key} = $invoice->{$key}->strftime('%B %d, %Y');
        }
    }

    my $invoice_dir = $config->get('invoice_dir');
    File::Path::make_path($invoice_dir);
    my $file = join '/', $invoice_dir, $invoice->{file};

    my $tt = Template->new;
    $tt->process( 'invoice.tex.tt', $invoice, $file )
        or die $tt->error . "\n";

    printf "Generated %s for %s: \$%.02f\n", $invoice->{file}, $custid,
        $invoice->{total};
}

$state->save;

sub round {
    my ($amount) = @_;

    #$amount =~ s/\.\d\d\K.*$//;
    #return $amount;
    return sprintf "%.02f", $amount;
}

sub find_customer_for_ticket {
    my ( $customers, $ticket ) = @_;

INVOICE: foreach my $cust ( values %{$customers} ) {
        next INVOICE unless $cust->{match};
        foreach my $m ( @{ $cust->{match} } ) {
            my $type = $m->{type};
            my $thing = join ' ', $ticket->$type;

            if ( $m->{$type} ) {
                my $match = lc $m->{$type};
                next INVOICE unless lc($thing) ~~ $match;
            }
            elsif ( $m->{regex} ) {
                next INVOICE unless $thing ~~ /\Q$m->{regex}\E/;
            }
            else {
                warn "Invalid match!";
                next INVOICE;
            }
        }
        return $cust;
    }

    return fake_customer( $customers, $ticket );
}

sub fake_customer {
    my ( $customers, $ticket ) = @_;

    my $cust = $config->get('default') || {};

    ( $cust->{id} ) = $ticket->requestors;
    return unless $cust->{id};

    $cust->{match} = [
        {   type  => 'requestors',
            regex => $cust->{id},
        }
    ];

    if ( my $invoice = make_invoice($cust) ) {
        $cust->{invoice} = $invoice;
    }

    $customers->{ $cust->{id} } = $cust;
    return $cust;
}

sub get_user {
    my ($id) = @_;

    state %users;
    return $users{$id} if $users{$id};

    my %map = (
        address_one   => 'addr1',
        address_two   => 'addr2',
        email_address => 'email',
        real_name     => 'name',
        name          => 'username',
    );

    my $users = RT::Client::REST::User->new( rt => $rt, id => $id );
    $users->retrieve;

    my %user;
    foreach my $m ( keys %{ $users->_attributes } ) {
        next unless $users->can($m);

        my $v = $users->$m;
        next unless $v;

        $m = $map{$m} if exists $map{$m};

        $user{$m} = $v;
    }

    $users{$id} = \%user;
    return \%user;
}

sub make_invoice {
    my ($cust) = @_;

    my $day  = $cust->{day}       ||= 1;
    my $per  = $cust->{per}       ||= 'week';
    my $freq = $cust->{frequency} ||= 1;

    my $day_method;
    given ($per) {
        when ('week')  { $per = 'weeks';  $day_method = 'dow' }
        when ('month') { $per = 'months'; $day_method = 'day' }
        default { die "Unknown per [$per]\n" }
    }

    my $billends = DateTime->now->set( hour => 0, minute => 0, second => 0 );

    # XXX This is helpful, but monthly and billday > 28 == !!!
    $billends->subtract( days => 1 ) while $billends->$day_method != $day;

    my $date = $billends->clone->subtract( $per => $freq );

    my %invoice = ( end => $billends->clone->subtract( seconds => 1 ) );

    my $lastinvoice = $state->last_invoice( $cust->{id} );
    if ( $lastinvoice->{date} ) {
        my $last_invoice_date = ymd_to_DateTime( $lastinvoice->{date} );
        $date = $last_invoice_date->clone->add( days => 1 );

        $invoice{start} = $date->clone;

        $startdate = $date->clone->subtract( $per => $freq )
            if !$startdate || $startdate > $date;
    }

    return if $billends <= $date;

    if ( $cust->{base_rate} ) {
        my ( $project, $hours ) = make_base_project(
            $cust,
            {   startdate  => $date,
                enddate    => $billends,
                per        => $per,
                freq       => $freq,
                day        => $day,
                day_method => $day_method,
            }
        );

        if ( @{ $project->{fees} } ) {
            $invoice{end}   = $project->{end};
            $invoice{hours} = $hours;
            push @{ $invoice{projects} }, $project;
        }
    }
    elsif ( $cust->{hours} ) {
        $invoice{hours} = [
            {   end   => $invoice{end}->clone,
                hours => $cust->{hours},
            }
        ];
    }

    return if $invoice{start} && $invoice{end} < $invoice{start};

    return \%invoice;
}

sub make_base_project {
    my ( $cust, $args ) = @_;

    my $date       = $args->{startdate};
    my $enddate    = $args->{enddate};
    my $per        = $args->{per};
    my $freq       = $args->{freq};
    my $day        = $args->{day};
    my $day_method = $args->{day_method};

    my $title
        = $freq == 1
        ? ucfirst( $cust->{per} . 'ly' )
        : $freq . ' ' . ucfirst( $cust->{per} );
    $title .= ' Retainer';

    my %project = ( title => $title, start => $date->clone, fees => [], );
    my @hours;

    while ( $date < $enddate ) {
        my $start = $date->clone;

        $date->add( $per => $freq );
        $date = $enddate->clone if $date > $enddate;

        # XXX This is helpful, but monthly and billday > 28 == !!!
        $date->subtract( days => 1 ) while $date->$day_method != $day;

        my $end = $date->clone->subtract( seconds => 1 );

        last if $end < $start;

        $project{end} = $end->clone;

        push @{ $project{fees} },
            {
            count    => 1,
            rate     => $cust->{base_rate},
            contents => $start->ymd . ' to ' . $end->ymd,
            };

        push @hours,
            {
            start => $start->clone,
            end   => $end->clone,
            hours => { %{ $cust->{hours} } },
            };
    }

    return \%project, \@hours;
}

sub make_address {
    my ($addr) = @_;
    my @adr;

    $addr = get_user($addr) unless ref $addr;

    if ( $addr->{organization} ) {
        push @adr, $addr->{organization};
    }
    elsif ( $addr->{name} && !$addr->{attn} ) {
        push @adr, $addr->{name};
    }

    if (   ( $addr->{addr1} || $addr->{addr2} )
        && $addr->{city}
        && $addr->{state}
        && $addr->{zip} )
    {
        push @adr, $addr->{attn}  if $addr->{attn};
        push @adr, $addr->{addr1} if $addr->{addr1};
        push @adr, $addr->{addr2} if $addr->{addr2};
        push @adr,
            $addr->{city} . ', ' . $addr->{state} . '  ' . $addr->{zip};
    }
    else {
        push @adr, $addr->{email} if $addr->{email};
    }

    return join "\n\n", @adr;
}

sub make_project {
    my ( $ticket, $cust ) = @_;

    my %project = (
        id     => $ticket->id,
        queue  => $ticket->queue,
        owner  => $ticket->owner,
        title  => $ticket->subject,
        detail => 'Ticket: '
            . $ticket->id
            . ' Status: '
            . $ticket->status
            . ' Requestors: '
            . join( ', ', $ticket->requestors ),
        fees     => [],
        expenses => [],
    );

    my $txns = $ticket->transactions( type => [qw(Comment Correspond)] );
    my $txn_i = $txns->get_iterator;
    while ( my $txn = $txn_i->() ) {
        next unless $txn->time_taken;
        next if $state->txn_is_invoiced( $txn->id );

        my $fee = make_fee( $txn, $cust->{rates}, $ticket );

        if ( !( $fee->{rate} && $fee->{count} ) ) {
            warn "Invalid Fee, no rate or count";
            next;
        }

        my $invoice = $cust->{invoice};
        next
            if $invoice->{start}
                && $invoice->{start} > $fee->{date};
        next if $invoice->{end} < $fee->{date};

        push @{ $project{fees} },         $fee;
        push @{ $project{transactions} }, $txn->id;
    }

    return \%project;
}

sub make_fee {
    my ( $txn, $rates, $ticket ) = @_;

    # XXX Only need $ticket for the alternate subject

    my $work_time = sprintf "%.03f", $txn->time_taken / 60;
    my $work_type = $txn->cf('WorkType');

    my %fee = (
        id       => $txn->id,
        contents => $txn->created . ' ('
            . $txn->id . ')' . "\n\n"
            . ( $txn->data || $ticket->subject ),
        count => $work_time,
        type  => $work_type,
        date  => ymd_to_DateTime( $txn->created ),
        rate  => $rates->{$work_type} || $rates->{default} || 0,
    );

    if ( $work_type && $work_type ne 'Normal' ) {
        $fee{detail} = $work_type . ' rate';
    }

    return \%fee;
}

sub hours_for_date {
    my ( $invoice, $date ) = @_;

    my $hours = {};
    if ( $invoice->{hours} ) {
        foreach my $h ( @{ $invoice->{hours} } ) {
            next if $h->{start} && $h->{start} > $date;
            next if $h->{end} < $date;

            $hours = $h->{hours};
            last;
        }
    }
    return $hours;
}

sub ymd_to_DateTime {
    my ($ymd) = @_;
    my ( $date, $time ) = split /[\sT]/, $ymd;
    my ( $year, $month, $day ) = split '-', $date;
    my ( $hour, $minute, $second ) = split ':', $time if $time;

    return DateTime->new(
        year   => $year,
        month  => $month,
        day    => $day,
        hour   => $hour || 0,
        minute => $minute || 0,
        second => $second || 0,
    );
}

package RTI::Config;
use strict;
use warnings;

use 5.010;

use YAML::Any qw/ LoadFile Dump Load /;
use File::Basename;

sub new {
    my ( $class, $args ) = @_;

    my $self = { file => '', };
    bless $self, $class;

    my $file = $args->{file} || $self->_find_config;
    $self->read_config($file);

    return $self;
}

sub _find_config {
    my ($self) = @_;

    # XXX This needs to be better
    foreach my $file (qw/ rt_invoice.conf rt_invoice.cfg .rt_invoicerc /) {
        foreach my $dir ( '.', $ENV{HOME} . '/.rt_invoicing', $ENV{HOME} ) {
            my $path = join '/', $dir, $file;
            return $path if -e $path;
        }
    }
    return;
}

sub read_config {
    my ( $self, $file ) = @_;

    $file ||= $self->{file};
    die "$file: no such file\n" unless -e $file;

    my $c = LoadFile($file) or die "Unable to load $file\n";

    $c->{customers} ||= {};
    if ( $c->{default} ) {
        foreach my $cust ( values %{ $c->{customers} } ) {
            foreach my $k ( keys %{ $c->{default} } ) {
                $cust->{$k} //= Load( Dump( $c->{default}->{$k} ) );
            }
        }
    }

    $self->{_config} = $c;
    $self->{file}    = $file;
}

sub get {
    my ( $self, $key ) = @_;
    my $value = Load( Dump( $self->{_config}->{$key} ) );

    return $value if $value;

    given ($key) {
        when ('state') {
            $value = $self->{file};
            $value =~ s/(?:\.[^.]+)?$/\.state/;
        }
        when ('invoice_dir') {
            $value = dirname( $self->{file} ) . '/invoices';
        }
    }

    return $value;
}

package RTI::State;
use strict;
use warnings;

use 5.010;

use YAML::Any qw/ LoadFile DumpFile /;

my $file = '';

sub new {
    my $class;
    ( $class, $file ) = @_;

    my $self = { lastinvoice => 0, };
    if ( -e $file ) {
        $self = LoadFile($file) or die "Unable to load state: $!";
    }

    bless $self, $class;

    die "Need to pass filename to new: $!" unless $file;

    return $self;
}

sub last_invoice {
    my ( $self, $custid ) = @_;
    state %table;
    if ( !%table ) {
        foreach my $date ( sort keys %{ $self->{invoice} } ) {
            while ( my ( $id, $inv ) = each %{ $self->{invoice}->{$date} } ) {
                next unless $inv->{custid};
                $table{ $inv->{custid} } = {
                    id   => $id,
                    date => $date,
                    %{$inv},
                };
            }
        }
    }
    return $table{$custid} || {};
}

sub txn_is_invoiced {
    my ( $self, $txn ) = @_;
    state %table;
    if ( !%table ) {
        foreach my $date ( sort keys %{ $self->{invoice} } ) {
            foreach my $inv ( values %{ $self->{invoice}->{$date} } ) {
                foreach my $t ( @{ $inv->{transactions} } ) {
                    $table{$t} = 1;
                }
            }
        }
    }
    return $table{$txn};
}

sub save {
    my ($self) = @_;
    DumpFile( $file, {%$self} ) or die "Unable to save state: $!";
}