#===============================================================================
#
#         FILE:  md5.t
#
#  DESCRIPTION:  Test Text::Todo::REST::API::md5
#
#       AUTHOR:  Andrew Fresh (AAF), andrew@cpan.org
#      COMPANY:  Red River Communications
#      CREATED:  01/07/10 19:11
#     REVISION:  $AFresh1: md5.t,v 1.4 2010/01/19 03:18:34 andrew Exp $
#===============================================================================

use strict;
use warnings;

use Test::More tests => 38;

my $class;
my $ext;

BEGIN {
    $ext = 'md5';

    $class = 'Text::Todo::REST::API';
    use_ok( $class, "use $class" );
}

diag("Testing entry $class $Text::Todo::REST::API::VERSION");

my $api = new_ok( $class,
    [ { todo_dir => 't/lists', path_info => '/todo.' . $ext } ] );

my $list_should_be = [
    {   'text' => '(A) entry 1 @one +uno',
        'md5'  => '931e0831c31a70928b29de55778dc294',
        'line' => 1
    },
    {   'text' => 'entry 2 @two +dos',
        'md5'  => 'b38dde8029c047e81379d9de581a6251',
        'line' => 2
    },
    {   'text' => '',
        'md5'  => 'd41d8cd98f00b204e9800998ecf8427e',
        'line' => 3
    },
    {   'text' => 'x completed entry 4',
        'md5'  => '8de0a2b65a50d5e30e84ad48af46fa78',
        'line' => 4
    },
    {   'text' => '(B) entry 5 is priority',
        'md5'  => 'c1692dfbf3b5829b6bce44b1a1614980',
        'line' => 5
    },
    {   'text' => 'entry 6 +delete',
        'md5'  => 'e1f6bf867f75aa019063782554407d02',
        'line' => 6
    }
];

my $list_dump_should_be = join q{},
    map { 'MD5 (' . $_->{text} . ') = ' . $_->{md5} . "\n" }
    @{$list_should_be};

my $result;
ok( !eval { $result = $api->_handle_representation('load') }, 'Load method' );
like( $@, '/^Unable to load \[list\]/', 'Failed Load as expected' );

$result = undef;
ok( !( $result = $api->Dump() ), 'Dump method' );
is( $result, undef, 'Dump returned undef' );

$result = undef;
ok( eval { $result = $api->Dump( @{$list_should_be} ) }, 'Dump method' );
is( $result, $list_dump_should_be, 'Got expected Dump result' );
$result = undef;

foreach my $e ( @{$list_should_be} ) {
    my $api = new_ok(
        $class,
        [   {   todo_dir => 't/lists',
                path_info => '/todo/entry/' . $e->{md5} . '.' . $ext
            }
        ]
    );
    my @entry;
    ok( @entry = $api->GET(), "get_entry by GET()" );
    is_deeply( \@entry, [$e], 'got correct entry' );

    my $result;
    ok( $result = $api->Dump(@entry), 'Dump output' );
    is( $result,
        'MD5 (' . $e->{text} . ') = ' . $e->{md5} . "\n",
        'Got correct Dump result'
    );
}