Return to GET.t CVS log

Up to [local] / todotxt / Text-Todo-REST-API / t

No longer try to make this module figure out the todo_dir and todo_file. Leave that up to Todo::Text of allow overriding by passing in todo_file and todo_dir.

#===============================================================================
#
#         FILE:  GET.t
#
#  DESCRIPTION:  Test Text::Todo::REST::API
#
#       AUTHOR:  Andrew Fresh (AAF), andrew@cpan.org
#      COMPANY:  Red River Communications
#      CREATED:  01/07/10 19:11
#     REVISION:  $AFresh1: GET.t,v 1.4 2010/01/18 13:47:53 andrew Exp $
#===============================================================================

use strict;
use warnings;

use Test::More tests => 16;
use Data::Dumper;

my $class;

BEGIN {
    $class = 'Text::Todo::REST::API';
    use_ok( $class, "use $class" );
}

diag("Testing GET $class $Text::Todo::REST::API::VERSION");

my $list_should_be = [
    {   'text' => '(A) entry 1 @one +uno',
        'md5'  => '931e0831c31a70928b29de55778dc294',
        'line' => 1
    },
    {   'text' => 'entry 2 @two +dos',
        'md5'  => 'b38dde8029c047e81379d9de581a6251',
        'line' => 2
    },
    {   'text' => '',
        'md5'  => 'd41d8cd98f00b204e9800998ecf8427e',
        'line' => 3
    },
    {   'text' => 'x completed entry 4',
        'md5'  => '8de0a2b65a50d5e30e84ad48af46fa78',
        'line' => 4
    },
    {   'text' => '(B) entry 5 is priority',
        'md5'  => 'c1692dfbf3b5829b6bce44b1a1614980',
        'line' => 5
    },
    {   'text' => 'entry 6 +delete',
        'md5'  => 'e1f6bf867f75aa019063782554407d02',
        'line' => 6
    }
];

my @pass = (
    {   path_info => '',
        result => ['todo.txt'],
    },
    {   path_info => '/todo',
        result => $list_should_be,
    },
    {   path_info => '/todo/list',
        result => $list_should_be,
    },
);

foreach my $p (@pass) {
    my $api = new_ok( $class,
        [ { todo_dir => 't/lists', path_info => $p->{path_info} } ] );

    my @result;
    ok( eval { @result = $api->GET() },
        'GET method (' . $p->{path_info} . ')'
    );
    is_deeply(
        \@result,
        $p->{result},
        'Failed GET as expected'
    );
}

my @fail = (
    {   path_info => '/todo/entry',
        result => '',
    },
    {   path_info => '/todo/unsupported',
        result => 'Unable to handle GET \[unsupported\]',
    },
);

foreach my $p (@fail) {
    my $api = new_ok( $class,
        [ { todo_dir => 't/lists', path_info => $p->{path_info} } ] );

    my $result;
    ok( !eval { $result = $api->GET() },
        'GET method (' . $p->{path_info} . ')'
    );
    like(
        $@,
        '/^' . $p->{result} . '/',
        'Failed GET as expected (' . $p->{result} . ')'
    );
}